Consider this scenario. You open the Home page of the web application that you are testing. In your Home page, you’ll have many links pointing to various sections of the website. Your task is to check that there should be no broken links (or dead links) in the Home page. i.e. All the links should open successfully without throwing ‘Page Not Found’ error.

The standard approach to find out the broken links in this case is depicted in the below flowchart.

Rather than using this method, we would try using a different way to check if the links available in a given page work properly or are broken. In this method, the code uses each of the links to create an HTTP Request. This request is then sent to the server and depending upon the response (e.g. 200 – Page Found, 404 – Page Not Found), you will come to know if the link is working or broken. With this method you can check if the page exists or not without opening the page directly.

Let’s see the code which you can use to find out broken links in your application.

'This is the main page
Browser("Browser").Page("HomePage").Sync

'Find out all the links in the page using ChildObjects
Set oLink = Description.Create
oLink("micclass").Value = "Link"
Set oAllLinks = Browser("Browser").Page("HomePage").ChildObjects(oLink)

'Find out the count of links
iTotalLinks = oAllLinks.Count

'Loop through all the links to find if the link is broken or not
For i=0 to iTotalLinks - 1

  'Find out the url for the link
  sURL = oAllLinks(i).GetROProperty("url")

  'Create a WinHTTP Request using the link's URL
  Set objWinHTTP = CreateObject("WinHttp.WinHttpRequest.5.1")
  objWinHTTP.Open "GET", sURL, False
  objWinHTTP.SetRequestHeader "User-Agent", "Mozilla/4.0 (compatible; MyApp 1.0; Windows NT 5.1)"

  'Send the Request to the Server and capture the response
  objWinHTTP.Send
  iReturnVal = objWinHTTP.Status

  'Find out if the Link exists or is broken
  If iReturnVal = 200 Then
	msgbox "Link - " & sURL & " Exists"
  ElseIf iReturnVal = 404 Then
	msgbox "Link - " & sURL & " is Broken"
  Else
    msgbox "Code" - iReturnVal
  End If

  Set objWinHTTP = Nothing

Next

The above example uses only 200 and 404 HTTP status codes. Below is the list of all the HTTP status codes that you can use to refine this code as per your requirement.

Use the comments section to let us know if this was useful for you. Happy Reading.. :–)

If you enjoyed this article, you can join our blog to get new articles delivered directly in your inbox.